ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_ScriptDate=1.8(August).2002
ERMS_PoweredBy=ERM Scripter v. 2004.10.5.945
;Dialogs for Silver
!#MCv9000:S@Текст@;
!#VRv9000:S9000;
!#MCv9001:S@Диалог@;
!#VRv9001:S9001;
!#MCv9002:S@Выбор@
!#VRv9002:9002;
!#MCv9003:S@Ввод@;
!#VRv9003:S9003;
!#MCv9004:S@Обнулить@;
!#VRv9004:S9004;
!?FU9000;
;x1 - индекс строки с текстом
;x2 - тип картинки
;x3 - подтип картинки
;Типы и подтипы картинок
;0..7 - [Ресурс] , [Кол-во]
;8 - [Артефакт] , [Номер артeфакта]
;9 - [Заклинание] , [Номер заклинания]
;10 - [Флаг] , [Номер флага]
;11 - [Положительная удача] , [1..3]
;12 - [Нейтральная удача] , [0]
;13 - [Отрицательная удача] , [1..3]
;14..16 - Тоже самое, только с моралью (14 - полож, 15 - нейтр, 16 - отриц)
;17 - [Опыт] , [Кол-во]
;20 - [Вторичный навык] , [Число = Навык*3+2+Уровень_Навыка]
;21 - [Монстр] , [Уровень_Монстра]
;22..30 - [Строения городов, 22 - Замок, 23 - Оплот вроде и т.д] [Номер строения]
;31..34 - [Первичный навык, 31 - Атака, 34 - Знания] , [Кол-во]
;35 - [Мана] , [Кол-во]
;36 - [Деньги] , [Кол-во]
!!IF:Q1/x2/x3/1/x1;
!?FU9001;
;x1 - индекс строки с путём к картинке из папки Maps
;z1 должна содержать текст, в одну строку
!!VRz-1:S^^;
!!IF:D100/1/-1/-1/x1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!IF:E1/100;
!?FU9005;
;*x1* - переменная
;*x2* - индекс v-переменной для получения результата
;вызывать через DO 0/30/1
;переменная, которая получит результат должна быть инициализированна в 0
!!VRy1:Sx1%2;
!!VRx16&y1=1:S30;
!!FU&y1=1:E;
!!VRvx2:+1;
!!VRx1::2;
!?FU9004;
;*x1*-*x13* - индексы строк для обнуления
!!VRzx1&x1<>0:S^^;
!!VRzx2&x2<>0:S^^;
!!VRzx3&x3<>0:S^^;
!!VRzx4&x4<>0:S^^;
!!VRzx5&x5<>0:S^^;
!!VRzx6&x6<>0:S^^;
!!VRzx7&x7<>0:S^^;
!!VRzx8&x8<>0:S^^;
!!VRzx9&x9<>0:S^^;
!!VRzx10&x10<>0:S^^;
!!VRzx11&x11<>0:S^^;
!!VRzx12&x12<>0:S^^;
!!VRzx13&x13<>0:S^^;
!?FU9002;
;Обнулите строки до выполнения этой команды!
;z1 должна хранить заголовок, а z2..z13 - варианты ответа
;v1 будет содержать номер выбранного ответа
!!IF:G1/10000/1/1/2/3/4/5/6/7/8/9/10/11/12/13;
!!VRv1:S0;
!!DO9005/0/30/1:Pv10000/1;
!?FU9003;
;*x1* - Кнопка Отмены существует (1) или нет (0)
;*x2* - индекс строковой переменной с белой строкой (0 - не используется)
;переменная z1 должна содержать текст.
;Переменная z1 возвратит введённый текст или переменная v1 будет равна -1, если нажата Отмена
!!VRz-1&x2=0:S^^;
!!VRz-1&x2<>0:Szx2;
!!VRz-2:S^^;
!!IF:D99/-1/1/-2/-2/-2/-2/-2/-2/-2/-2/-2/-2/-2/-2/-2;
!!IF:F99/-2/-2/-2/-2/x1;
!!IF:E1/99;
Уже слал Сильверу. Кто хоть немного знает ЕРМ, поймёт, что есть 5 ключевых функций.
Код
Текст
Ввод
Выбор
Обнулить
Диалог
Вызываются так:
!?событие...
!!FU$Текст$:P(параметры....)
Смотрим, функция Текст. Три параметра:
;x1 - индекс строки с текстом
;x2 - тип картинки
;x3 - подтип картинки
Наш код:
Код
!!VRz1:S^Привет, Готический город!^; присваиваем z1 строку
!!FU$Текст$:P1/12/0;
Если посмотреть на список параметров, то 12/0 - это нейтральная удача.
Тот же $диалог$ вообще один параметр принимает:
Код
!!VRz1:S^Это - однострочный текст^;
!!VRz2:S^..\Data\Моя_картинка.jpg^;
!!FU$Диалог$:P2;
Разберётесь, в общем.